*        TEST.PRG :  LES TESTS EN PRATIQUE
*
CAL 47 1 4
COMPUTE NBEG=47:1 , NEND=79:3
ALLOCATE NEND
*
OPEN DATA C:\T837\DAT\GNPM1.DAT
DATA NBEG NEND GNP M1
*
COMPUTE NLAG=8
DOFOR I = GNP M1
 LOG I
END DO
DIFF(DIFFS=1) GNP / GNP_D
DIFF(DIFFS=1) M1 / M1_D
*
*             Le modèle non-contraint:  H1:  variables retardées incluses
*
LINREG GNP_D NBEG+NLAG+1 NEND RESNC
# CONSTANT M1_D{0 TO NLAG}
COMPUTE RSSNC = %RSS, SEESQNC = %RSS/%NOBS
DISPLAY 'NOBS = ' %NOBS
*
*             Test de WALD sous la forme Rb = r
*
EXCLUDE
# M1_D{1 TO NLAG}
*
*             Le modèle contraint:  H0:  variables retardées exlues
*
LINREG GNP_D NBEG+NLAG+1 NEND RESC
# CONSTANT M1_D
COMPUTE RSSC=%RSS, SEESQC = %RSS/%NOBS
*
*             Test de WALD sous la forme RSSC-RSSNC:  distribution F
*
COMPUTE WALD_F = ( (RSSC-RSSNC)/NLAG ) / ( RSSNC/(%NOBS-NLAG-2) )
CDF FTEST WALD_F NLAG %NOBS-NLAG-2
*
*             Test de WALD sous la forme RSSC-RSSNC:  distribution X2
*
COMPUTE WALD_C = WALD_F*NLAG
CDF CHISQUARED WALD_C NLAG
COMPUTE WALD_C = (RSSC-RSSNC)/(RSSNC/%NOBS)
CDF CHISQUARED WALD_C NLAG
*
*             Test du RV sous la forme T[log SIG(H0) - log SIG(H1) ]
*
COMPUTE LR = %NOBS*(LOG(SEESQC)-LOG(SEESQNC))
CDF CHISQUARED LR NLAG
*
*             Le meme resultat s'obtient avec RSS
*
COMPUTE LR = %NOBS*(LOG(RSSC)-LOG(RSSNC))
CDF CHISQUARED LR NLAG
*
RATIO(DEGREES=NLAG) NBEG+NLAG+1 NEND
# RESNC
# RESC
*
*             Test du RV sous la forme RSSC-RSSNC
*
COMPUTE LR =  (RSSC-RSSNC) / ( SQRT(RSSC/%NOBS)*SQRT(RSSNC/%NOBS) )
CDF CHISQUARED LR NLAG
*
*             Test de LAGRANGE sous la forme RSSC-RSSNC
*
COMPUTE LM = (RSSC-RSSNC) / (RSSC/%NOBS)
CDF CHISQUARED LM NLAG
*
*             Test de LAGRANGE sous la forme TR2
*
LINREG RESC NBEG+NLAG+1 NEND
# CONSTANT M1_D M1_D{1 TO NLAG}
CDF CHISQUARED %TRSQ NLAG            ;* Test de Lagrange:
*                                       exclusion des variables retardées