*        GRANGER.PRG: Reprise de l'étude de Granger et Newbold (1974)
*
COMPUTE NOBS=100
COMPUTE NDRAWS=1000
*
ALLOCATE 2 NOBS+1
*
COMPUTE SUM_R2=0.0 , FAUX_T=0.0 , SUM_BETA=0.0 , COMPTEUR=0.0
COMPUTE VAR_BETA=0.0 , SUM_ECT=0.0 , TTEST=0.0
ZERO Y1 1 100 ; ZERO Y2 1 100
*
EQUATION 1 Y1
# Y1{1}
ASSOCIATE(VARIANCE=1.0) 1
# 1
EQUATION 2 Y2
# Y2{1}
ASSOCIATE(VARIANCE=1.0) 2
# 1
*
*SIMULATE 2 NOBS 2
*# 1 Y1 2
*# 2 Y2 2
*
DO I=1,NDRAWS
   SIMULATE 2 NOBS 2
   # 1 Y1 2
   # 2 Y2 2
*
   LINREG(NOPRINT) Y2 2 NOBS+1
   # CONSTANT Y1
*
   COMPUTE SUM_R2 = SUM_R2 + %RSQUARED
   COMPUTE TTEST = %BETA(2)/SQRT(%SEESQ*%XX(2,2))
   COMPUTE FAUX_T = FAUX_T + ABS(TTEST)
   COMPUTE SUM_BETA = SUM_BETA + %BETA(2)
   COMPUTE VAR_BETA = VAR_BETA + (%BETA(2)**2)
   COMPUTE SUM_ECT = SUM_ECT + (SQRT(%SEESQ*%XX(2,2)))
*
   IF TTEST.GT.1.64
      COMPUTE COMPTEUR = COMPTEUR + 1.0
*
END DO I
*
COMPUTE SUM_R2 = SUM_R2/NDRAWS
COMPUTE FAUX_T = FAUX_T/NDRAWS
COMPUTE SUM_BETA = SUM_BETA/NDRAWS
COMPUTE COMPTEUR = COMPTEUR/NDRAWS
COMPUTE VAR_BETA = (VAR_BETA/NDRAWS) - (SUM_BETA**2)
COMPUTE VRAI_ECT = SQRT(VAR_BETA)
COMPUTE SUM_ECT = SUM_ECT/NDRAWS
*
DISPLAY 'LA MOYENNE DES BETAS' SUM_BETA
DISPLAY 'LA MOYENNE DES ECARTS-TYPES' SUM_ECT
DISPLAY 'LA MOYENNE DES TESTS T' FAUX_T
DISPLAY 'LA MOYENNE DES R2' SUM_R2
DISPLAY 'LE % DES REGRESSIONS SIGNIFICATIVES' COMPTEUR
*
DISPLAY 'LE VRAI ECART-TYPE' VRAI_ECT
COMPUTE VRAI_T = SUM_BETA/VRAI_ECT
DISPLAY 'LE VRAI TEST-T ' VRAI_T
*
*  Seulement, 5% des régressions devraient être significatives
*
END