*        ESTI.PRG :  ESTIMATION D'UN AR(1)
*
ALL 100
COMPUTE NBEG=2 , NEND=100
COMPUTE DELTA=2.0 , PHI=0.5 , VAR_E=1.0
CLEAR Y
SEED 4
*
*        Première observation
*
EQUATION 1 Y
# CONSTANT
ASSOCIATE(VARIANCE=VAR_E/(1-PHI**2)) 1
# DELTA/(1-PHI)
SIMULATE 1 1 1
# 1 Y
DISPLAY Y(1)
*
*        Autres observations
*
EQUATION 1 Y
# CONSTANT Y{1}
ASSOCIATE(VARIANCE=1) 1
# DELTA PHI
SIMULATE 1 NEND-1 NBEG
# 1 Y NBEG
*
*        Moindres carrés
*
LINREG Y NBEG NEND
# CONSTANT Y{1}
*
*        Vraisemblance maximale - méthode itérative
*
COMPUTE NOBS = NEND-NBEG+1
COMPUTE Y1 = Y(1)
NONLIN DELTA PHI SIGMASQ
FRML OLSRESID = Y-DELTA-PHI*Y{1}
FRML AR1_VR = -(NOBS/2)*LOG(SIGMASQ) + 0.5*LOG(1-PHI**2) $
              -(0.5/SIGMASQ)*(1-PHI**2)*(Y1**2) $
              -0.5*(OLSRESID**2)/SIGMASQ
COMPUTE DELTA=%BETA(1) , PHI=%BETA(2) , SIGMASQ=%SEESQ
NLPAR(SUBITERATIONS=100)
MAXIMIZE(ITERATIONS=50) AR1_VR NBEG NEND
*
*       Attention à l'instruction NLPAR :  la valeur de défaut de 10 n'est pas suffisante
*       ici Il est possible de ne calculer que la fonction de vraisemblance en spécifiant
*       ITERATIONS=0 dans MAXIMIZE.
*
*       Méthode des moments
*
INSTRUMENTS CONSTANT Y{2}
LINREG(INST) Y
# CONSTANT Y{1}
*
SOURCE C:\T837\SUB\MIXED.SRC
DECLARE RECT CAPR(1,2)
INPUT CAPR
 0.0 1.0
DECLARE  VECT LOWR(1)
INPUT LOWR
  .8
DECLARE  SYMM V(1,1)
INPUT V
  .01
@MIXED Y 2 NOBS CAPR LOWR V
# CONSTANT Y{1}
END