*       COINT3.PRG :  La formulation correction d'erreur
*       Voir le texte «Toujours plus haut» pour la valeur
*       des coefficients
*
ALL 100
SEED 4
ZERO Y1; ZERO Y2; ZERO Y3; ZERO Y1_D; ZERO Y2_D; ZERO Y3_D
ZERO COINT1; ZERO COINT2; ZERO COINT3
*
*       Le modèle à correction d'erreur sous forme matricielle
*
*       W(t)         = C + PHI*W(T-1) + DEL*B*Y(T-1) +E(t)
*       Y(t)-Y(t-1)  = C + PHI*W(T-1) +    PI*Y(T-1) +E(t)
*
*       si PHI = 0, alors
*
*       Y(t) = C + (I+PI)*Y(T-1) +E(t)
*
DEC VECTOR C(3)
DEC RECT   DEL(3,3)
DEC RECT   B(3,3)
DEC RECT   PHI(3,3)
*
INPUT C
0 0 0
INPUT DEL
 0   0    0
.1   0    0
.1  .1    0
INPUT B
1  -1  -1
0   1  -1
0   0   0
INPUT PHI
0   0   0
0   0   0
0   0   0
*
*      Calculs de racines pour vérifier le rang de PI et les racines unitaires
*      de I+PI
*
COMPUTE PI = DEL*B
EIGEN(CVALUES=CROOTS) PI
WRITE CROOTS
*
COMPUTE A=%IDENTITY(3)
COMPUTE PHIL=A+PI
EIGEN(CVALUES=CROOTS) PHIL
WRITE CROOTS
*
*       Création des équations
*
EQUATION 1 Y1_D
# CONSTANT Y1_D{1} Y2_D{1} Y3_D{1} COINT1{1} COINT2{1} COINT3{1}
ASSOCIATE(VAR=1.0) 1
# C(1) PHI(1,1) PHI(1,2) PHI(1,3) DEL(1,1) DEL(1,2) DEL(1,3)
EQUATION 2 Y2_D
# CONSTANT Y1_D{1} Y2_D{1} Y3_D{1} COINT1{1} COINT2{1} COINT3{1}
ASSOCIATE(VAR=1.0) 2
# C(2) PHI(2,1) PHI(2,2) PHI(3,3) DEL(2,1) DEL(2,2) DEL(2,3)
EQUATION 3 Y3_D
# CONSTANT Y1_D{1} Y2_D{1} Y3_D{1} COINT1{1} COINT2{1} COINT3{1}
ASSOCIATE(VAR=1.0) 3
# C(3) PHI(3,1) PHI(3,2) PHI(3,3)  DEL(3,1) DEL(3,2) DEL(3,3)
*
EQUATION(IDENTITY) 4 Y1
# Y1{1} Y1_D
ASSOCIATE 4
# 1 1
EQUATION(IDENTITY) 5 Y2
# Y2{1} Y2_D
ASSOCIATE 5
# 1 1
EQUATION(IDENTITY) 6 Y3
# Y3{1} Y3_D
ASSOCIATE 6
# 1 1
EQUATION(IDENTITY) 7 COINT1
# Y1 Y2 Y3
ASSOCIATE 7
# B(1,1) B(1,2) B(1,3)
EQUATION(IDENTITY) 8 COINT2
# Y1 Y2 Y3
ASSOCIATE 8
# B(2,1) B(2,2) B(2,3)
EQUATION(IDENTITY) 9 COINT3
# Y1 Y2 Y3
ASSOCIATE 9
# B(3,1) B(3,2) B(3,3)
*
*        Simulation du modèle
*
SIMULATE 9 97 3
# 1 Y1_D
# 2 Y2_D
# 3 Y3_D
# 4 Y1
# 5 Y2
# 6 Y3
# 7 COINT1
# 8 COINT2
# 9 COINT3
*
*        Graphiques
*
SPGRAPH(VFIELDS=2,HFIELDS=2)
GRAPH(HEADER='Séries Y1,Y2 ET Y3 en niveau') 3
# Y1 3 99
# Y2 3 99
# Y3 3 99
SCATTER 2
# Y1 Y2
# Y1 Y3
GRAPH(HEADER='COINT1') 1
# COINT1 3 99
GRAPH(HEADER='COINT2') 1
# COINT2 3 99
SPGRAPH(DONE)