*        ARMA.PRG : PROPRIÉTÉS DYNAMIQUES DES MODÈLES ARMA
*
ALL 100;  ZERO Y1
*                       AR(1)
*
EQUATION 1 Y1
# CONSTANT Y1{1}
ASSOCIATE(VARIANCE=1.0) 1
# 0.0 0.5
IMPULSE 1 12
# 1 S1
*                       AR(2)  lisse
*
EQUATION 1 Y1
# CONSTANT Y1{1 TO 2}
ASSOCIATE(VARIANCE=1.0) 1
# 0.0 0.5 0.2
IMPULSE 1 12
# 1 S2
COMPUTE [RECTANGULAR] PHI = ||0.5,0.2|1,0||
EIGEN(CVALUES=CEIGEN) PHI EIGEN MEIGEN
WRITE EIGEN CEIGEN MEIGEN
*
*                       AR(2) lisse:  version canonique
*
EQUATION 1 Y1
# CONSTANT Y1{1}
ASSOCIATE(VARIANCE=1.0) 1
# 0 EIGEN(1)
EQUATION 2 Y2
# CONSTANT Y2{1}
ASSOCIATE(VARIANCE=1.0) 2
# 0 EIGEN(2)
EQUATION(IDENTITY) 3 Y3
# Y1 Y2
ASSOCIATE 3
# MEIGEN(1,1) MEIGEN(1,2)
*
DEC VECTOR Y_1(2) Z_1(2)
COMPUTE Y_1(1)=1.0, Y_1(2)=0.0
COMPUTE Z_1 = INV(MEIGEN)*Y_1 ;* Calcul des chocs initiaux Z=(M^-1)*Y
IMPULSE(INPUT) 3 12
# 1
# 2
# 3
# Z_1(1) Z_1(2) 0
*
*                       AR(2)  oscillant
*
EQUATION 1 Y1
# CONSTANT Y1{1 TO 2}
ASSOCIATE(VARIANCE=1.0) 1
# 0.0 -0.5 0.2
IMPULSE 1 12
# 1 S3
COMPUTE [RECTANGULAR] PHI = ||-0.5,0.2|1,0||
EIGEN(CVALUES=CEIGEN) PHI EIGEN
WRITE EIGEN CEIGEN
*
*                       AR(2)  "montagnes russes"
*
EQUATION(AR=INPUT) 1 Y1
# 1 2
ASSOCIATE(VARIANCE=1.0) 1
# 0.0 1.25 -0.40
IMPULSE 1 12
# 1 S4
COMPUTE [RECTANGULAR] PHI = ||1.25,-0.4|1,0||
EIGEN(CVALUES=CEIGEN) PHI EIGEN
WRITE EIGEN CEIGEN
*                       AR(2)  non stationnaire
*
EQUATION 1 Y1 2
ASSOCIATE(VARIANCE=1.0) 1
# 0.0 1.25 -0.10
IMPULSE 1 12
# 1  S5
COMPUTE [RECTANGULAR] PHI = ||1.25,-0.1|1,0||
EIGEN(CVALUES=CEIGEN) PHI EIGEN
WRITE EIGEN CEIGEN
*
*                       MA(1)  coupure dans la persistence
*
EQUATION 1 Y1 0 1
ASSOCIATE(VARIANCE=1.0) 1
# 0.0 0.8
IMPULSE 1 12
# 1 S6
*                       MA(2) "non-invertible"
*
EQUATION 1 Y1 0 2
ASSOCIATE(VARIANCE=1.0) 1
# 0.0 0.5 0.8
IMPULSE 1 12
# 1 S7
COMPUTE [RECTANGULAR] THETA = ||0.5,0.8|1,0||
EIGEN(CVALUES=CEIGEN) THETA EIGEN
WRITE EIGEN CEIGEN
*
*                       ARMA(1,1)  "montagne russe"
*
EQUATION 1 Y1 1 1
ASSOCIATE(VARIANCE=1.0) 1
# 0.0 0.5 0.8
IMPULSE 1 12
# 1 S8
*
OPEN PLOT C:\T837\GRA\ARMA.RGF
GRPARM(PORTRAIT)
SPGRAPH(HEADER='Pot-pourri des modèles ARMA',VFIELD=4,HFIELD=2)
GRAPH(HEADER='AR(1)',MAX=1.3,MIN=-.5,STYLE=BAR) 1
# S1 / 2
GRAPH(HEADER='AR(2) LISSE',MAX=1.3,MIN=-.5,STYLE=BAR) 1
# S2 / 2
GRAPH(HEADER='AR(2) OSCILLANT',MAX=1.3,MIN=-.5,STYLE=BAR) 1
# S3 / 2
GRAPH(HEADER='AR(2) MONTAGNES RUSSES',MAX=1.3,MIN=-.5,STYLE=BAR) 1
# S4 / 2
GRAPH(HEADER='AR(2) NON STATIONNAIRE',MAX=1.3,MIN=-.5,STYLE=BAR) 1
# S5 / 2
GRAPH(HEADER='MA(1)',MAX=1.3,MIN=-.5,STYLE=BAR) 1
# S6 / 2
GRAPH(HEADER='MA(2)',MAX=1.3,MIN=-.5,STYLE=BAR) 1
# S7 / 2
GRAPH(HEADER='ARMA(1,1)',MAX=1.3,MIN=-.5,STYLE=BAR) 1
# S8 / 2
SPGRAPH(DONE)