*        NON_STAT.PRG: ANALYSE DE DONNÉES NON STATIONNAIRES FICTIVES
*
COMPUTE NBEG=5 , NEND=100+NBEG , NOBS=100 , NLAG=12
ALLOCATE NEND
SEED 4
ZERO Y1 ; ZERO Y2 ; ZERO Y3 ; ZERO Y4 ; ZERO Y5
SET TREND 1 NEND = T
*
*        Modèle AR(2) avec racine unitaire
*        (1-0.5L)(1-L)Y1(t) = e(t)
*
EQUATION 1 Y1
# Y1{1 2}
ASSOCIATE(VARIANCE=1.0) 1
# 1.5 -.5
*
*        AR(1) stationnaire
*        (1-0.5L)Y2(t) = e(t)
*
EQUATION 2 Y2
# Y2{1}
ASSOCIATE(VARIANCE=4.0) 2
# 0.5
*
*        Tendance déterministe plus composante stationnaire
*        Y3(t) =  1.0 + TREND + Y2(t)
*
EQUATION(IDENTITY) 3 Y3
# CONSTANT TREND Y2
ASSOCIATE(VARIANCE=1.0) 3
# 1.0 1.0 1.0
*
*        Tendance stochastique plus composante stationnaire
*        Y4(T) = Y1(t) + Y2(t)
*
EQUATION(IDENTITY) 4 Y4
# Y1 Y2
ASSOCIATE 4
# 1.0 1.0
*
*        Marche aléatoire
*        Y5(t) = Y5(t-1) + e(t)
*
EQUATION 5 Y5
# Y5{1}
ASSOCIATE(VARIANCE=1.0) 5
# 1.0
*
SIMULATE 5 103 NBEG-2
# 1 Y1 NBEG-2
# 2 Y2 NBEG-2
# 5 Y5 NBEG-2
# 3 Y3 NBEG-2
# 4 Y4 NBEG-2
*
*        La régression de Y1 sur une tendance donne
*        une fausse impression
*
LINREG Y1 NBEG NEND Y1_DEV
# CONSTANT TREND
PRJ Y1_TEND
*
*        Prendre les déviations par rapport à une tendance linéaire
*        introduit une trop grande persistence dans les résidus
*
CORRELATE(NUMBER=NLAG) Y1_DEV NBEG NEND
*
*        La première différence est la transformation la plus appropri‚e
*        quand il y a une racine unitaire
*
DIFF Y1 NBEG NEND Y1_D
CORRELATE(NUMBER=NLAG) Y1_D NBEG NEND
*
*        La série Y3 est stationnaire par rapport à une tendance
*
LINREG Y3 NBEG-2 NEND Y3_DEV
# CONSTANT TREND
CORRELATE(NUMBER=NLAG) Y3_DEV NBEG NEND
STATISTICS Y3_DEV NBEG NEND
LINREG Y3_DEV NBEG NEND
# Y3_DEV{1}
*
*        Prendre une premire différence de Y3 n'est pas appropriée
*
DIFF Y3 NBEG NEND Y3_D
STATISTICS Y3_D NBEG NEND
CORRELATE(NUMBER=NLAG) Y3_D NBEG NEND
*
*        Le choix de la mauvaise transformation peut avoir
*        des conséquences facheuses.  Par exemple, il est à la
*        source de régressions illusoires comme
*
LINREG Y1 NBEG NEND Y1_RES
# CONSTANT Y5
CORRELATE(NUMBER=NLAG) Y1_RES NBEG NEND
*
*        Par contre, nous verrons que la régression suivante est
*        admissible
*
LINREG Y4 NBEG NEND
# CONSTANT Y1
*
SMPL NBEG NEND
OPEN PLOT C:\T837\GRA\NON_STAT.RGF
GRPARM(PORTRAIT) HEADER 28
SPGRAPH(HFIELDS=2,VFIELDS=3)
  GRAPH(HEADER='Stationnaire en différence',KEY=LORIGHT) 2
  # Y1
  # Y1_TEND
  GRAPH(SAMESIZE,KEY=LORIGHT) 1
  # Y1_DEV
  GRAPH(SAMESIZE,KEY=LORIGHT) 1
  # Y1_D
  GRAPH(SAMESIZE,HEADER='Stationnaire en tendance',KEY=LORIGHT) 2
  # Y3
  # TREND
  GRAPH(SAMESIZE,KEY=LORIGHT) 1
  # Y3_DEV
  GRAPH(SAMESIZE,KEY=LORIGHT) 1
  # Y3_D
SPGRAPH(DONE)