*        MANKIW_2.PRG: Suite de Mankiw et Campbell (1987)
*
CAL 1947 1 4; ALL 89:1
COMPUTE NBEG=47:1, NEND=89:1, FBEG=86:1, FEND=88:4, NSTEP=12
OPEN DATA C:\T837\DAT\USAQ.RAT
DATA(FORMAT=RATS) NBEG NEND RGNP
*
LOG RGNP
DIFF(DIFFS=1) RGNP NBEG+1 NEND RGNPD NBEG+1
SET TREND NBEG NEND = T
*
*        Calculs avec première différence
*
LINREG(DEFINE=1) RGNPD NBEG+2 FBEG-1
# CONSTANT RGNPD{1}
IMPULSE(INPUT) 1 NSTEP+1
# 1
# 1.0
*
FORECAST 1 NSTEP FBEG
# 1 PRGNPD FBEG
ERRORS 1 NSTEP
# 1 ERGNPD FBEG
SET LSD FBEG FEND = PRGNPD+1.15*ERGNPD ;* Intervalle de confiance a 75%
SET LID FBEG FEND = PRGNPD-1.15*ERGNPD
PRINT FBEG FEND LSD PRGNPD LID
*
*        Transformation en niveau
*
MODIFY 1 2
VREPLACE RGNPD BY RGNP DIFFERENCE 1
IMPULSE(INPUT) 1 NSTEP+1
# 2
# 1.0
*
FORECAST 1 NSTEP FBEG
# 2 PRGNP FBEG
ERRORS 1 NSTEP
# 2 ERGNP FBEG
SET LS FBEG FEND = PRGNP+1.15*ERGNP
SET LI FBEG FEND = PRGNP-1.15*ERGNP
PRINT FBEG FEND LS PRGNP LI
*
*        Modèle avec une tendance selon Blanchard
*
LINREG(DEFINE=3) RGNP NBEG+4 FBEG-1
# CONSTANT TREND RGNP{1 TO 4}
IMPULSE(INPUT) 1 NSTEP+1
# 3
# 1.0
FORECAST 1 NSTEP FBEG
# 3 PRGNPT FBEG
ERRORS 1 NSTEP
# 3 ERGNPT FBEG
SET LST FBEG FEND = PRGNPT+1.15*ERGNPT
SET LIT FBEG FEND = PRGNPT-1.15*ERGNPT
PRINT FBEG FEND LST PRGNPT LIT
*
*        Graphiques
*
OPEN PLOT C:\T837\GRA\MANKIW2.RGF
GRPARM
SPGRAPH(VFIELDS=3)
  GRAPH(HEADER='Prévision en différence') 4
  # RGNPD FBEG-8 FBEG-1
  # PRGNPD FBEG FEND 7
  # LSD FBEG FEND 6
  # LID FBEG FEND 6
  GRAPH(HEADER='Prévision en niveau') 4
  # RGNP FBEG-8 FBEG-1
  # PRGNP FBEG FEND 7
  # LS FBEG FEND 6
  # LI FBEG FEND 6
  GRAPH(HEADER='Prévision avec tendance') 4
  # RGNP FBEG-8 FBEG-1
  # PRGNPT FBEG FEND 7
  # LST FBEG FEND 6
  # LIT FBEG FEND 6
SPGRAPH(DONE)