*       ENDERS2.PRG :  Reprise de l'exemple de Enders (1996)
*                      Rats Handbook for Econometric Time Series
*                      P.168-172
*                      Ajout de la procédure de Johansen
CAL 1960 1 4
ALL 10 1991:4
COMPUTE NBEG=60:1, NEND=91:4
OPEN DATA C:\T837\ENDERS\US.PRN
DATA(FORMAT=PRN,ORG=OBS) / TBILL R3 R10
*
GRAPH(HEADER='Taux d intérêt US 1960-91',SUBHEAD='Rats Handbook par Enders', $
      KEY=UPLEFT) 3
# TBILL
# R3
# R10
*
*        Test de Dickey-Fuller sur chaque taux d'intérêt
*
SOURCE(NOECHO) C:\T837\SUB\DFUNIT.SRC
@DFUNIT(NOTREND,TTEST,LAGS=2) TBILL
@DFUNIT(NOTREND,TTEST,LAGS=2) R3
@DFUNIT(NOTREND,TTEST,LAGS=2) R10
*
*        Estimation d'une relation de cointégration i.e. combinaison
*        linéaire stationnaire
*
LINREG TBILL / RES
# CONSTANT R3 R10
COMPUTE B0=%BETA(1),B1=%BETA(2),B2=%BETA(3)
SET RESID / = TBILL - B0-B1*R3-B2*R10
SET RESID1 / = RESID{1}
*
*        Test de Dickey-Fuller sur les résidus
*
DIFF RES / RES_D
LINREG RES_D
# RES{1} RES_D{1}
*
GRAPH(HEADER='Combinaison linéaire stationnaire') 1
# RESID
*
*         Estimation d'un modèle à correction d'erreur
*         Enders postule un modèle avec deux retards
*
DIFF TBILL / TBILL_D
DIFF R3    / R3_D
DIFF R10   / R10_D
*
SYSTEM 1 TO 3
VAR TBILL_D R3_D R10_D
LAG 1 TO 2
DET RESID1
END(SYSTEM)
ESTIMATE NBEG+3 NEND
*
*          Analyse de cointégration multivariée
*
SOURCE(NOECHO) C:\T837\SUB\JOHANSEN.400
@JOHANSEN(LAGS=2) 60:1 91:4
# TBILL R3 R10
*
*          Estimation de deux relations de cointégration
*          identifiées
*          Le programme Johansen.400 ne donne pas de constante
*          dans la relation de cointégration
*
LINREG TBILL NBEG NEND
# CONSTANT R3 R10
COMPUTE B0=%BETA(1), B1=%BETA(2), B2=%BETA(3)
SET Z NBEG NEND = TBILL - %BETA(1)-%BETA(2)*R3-%BETA(3)*R10
SET Z1 NBEG+1 NEND = Z{1}
LINREG R3 NBEG NEND
# CONSTANT R10
COMPUTE B4=%BETA(1), B5=%BETA(2)
SET Y NBEG NEND = R3 - %BETA(1) -%BETA(2)*R10
SET Y1 NBEG+1 NEND = Y{1}
*
*           Estimation d'un modèle à correction d'erreur
*
SYSTEM 1 TO 3
VAR TBILL_D R3_D R10_D
LAG 1 TO 2
DET Z1 Y1
END(SYSTEM)
ESTIMATE(OUTSIGMA=OMEGA) NBEG+3 NEND
*
*          Transformation des équations pour passer
*          de différence à niveau
*
MODIFY 1 4
VREPLACE TBILL_D BY TBILL DIFF 1
VREPLACE R3_D BY R3 DIFF 1
VREPLACE R10_D BY R10 DIFF 1
MODIFY 2 5
VREPLACE TBILL_D BY TBILL DIFF 1
VREPLACE R3_D BY R3 DIFF 1
VREPLACE R10_D BY R10 DIFF 1
MODIFY 3 6
VREPLACE TBILL_D BY TBILL DIFF 1
VREPLACE R3_D BY R3 DIFF 1
VREPLACE R10_D BY R10 DIFF 1
*
*          Création d'identités pour les relations de cointégration
*
EQUATION(IDENTITY) 7 Z
# TBILL CONSTANT R3 R10
ASSOCIATE 7
# 1 -B0 -B1 -B2
EQUATION(IDENTITY) 8 Y
# R3 CONSTANT R10
ASSOCIATE 8
# 1 -B4 -B5
*
*          Analyse de chocs comme à l'habitude avec un ordonnancement
*          (discutable) TBILL-R3-R10
*
ERRORS(IMPULSE) 5 12 OMEGA
# 4
# 5
# 6
# 7
# 8
END